dotfiles/systems/deimos/config/filesystem.nix

{
  flake,
  config,
  ...
}:
let
  inherit (flake.config.people) user0;
  inherit (flake.config.machines.devices) deimos ceres eris;

  sambaSecrets = config.sops.secrets."network/server".path;
in
{
  fileSystems =
    let
      erisDrives = [
        "samba0"
      ];
      erisFolders = [
        "raid0"
      ];
      ceresDrives = [
        "samba0"
      ];
      ceresFolders = [
        "storage"
      ];
      erisMounts = sambaDrive: folder: {
        name = "${eris.${sambaDrive}.mount}/${folder}";
        value = {
          device = "${eris.${sambaDrive}.device}/${folder}";
          fsType = "cifs";
          options = eris.${sambaDrive}.options ++ [
            "credentials=${sambaSecrets}"
          ];
        };
      };
      ceresMounts = sambaDrive: folder: {
        name = "${ceres.${sambaDrive}.mount}/${folder}";
        value = {
          device = "${ceres.${sambaDrive}.device}/${folder}";
          fsType = "cifs";
          options = ceres.${sambaDrive}.options ++ [
            "credentials=${sambaSecrets}"
          ];
        };
      };
    in
    {
      "/" = {
        device = "/dev/disk/by-uuid/aa9e7283-3e96-4d3e-a66b-ce24bba9f3f2";
        fsType = "ext4";
      };
      "/boot" = {
        device = "/dev/disk/by-uuid/0616-DAE7";
        fsType = "vfat";
        options = deimos.boot.options;
      };
    }
    // (builtins.listToAttrs (
      builtins.concatMap (drive: map (folder: ceresMounts drive folder) ceresFolders) ceresDrives
    ))
    // (builtins.listToAttrs (
      builtins.concatMap (drive: map (folder: erisMounts drive folder) erisFolders) erisDrives
    ));

  swapDevices = [
    { device = "/dev/disk/by-uuid/027a1efb-6c4e-4c1a-9956-91c7513950b4"; }
  ];

  systemd.tmpfiles.rules = [
    "Z ${config.home-manager.users.${user0}.home.homeDirectory} 0755 ${user0} users -"
  ];

  services.udisks2.enable = true;
}