dotfiles/modules/nixos/services/forgejo/default.nix

{
  flake,
  config,
  pkgs,
  ...
}:
let
  inherit (flake.config.machines.devices) ceres;
  inherit (flake.config.services)
    instances
    ;
  service = instances.forgejo;
  localhost = instances.web.localhost.address0;
  host = service.domains.url0;

  caddy = instances.caddy;
  postgres = instances.postgresql;
  syncthing = instances.syncthing;
  backupPath = "${instances.syncthing.paths.path1}/${service.name}";
in
{
  services = {
    forgejo = {
      enable = true;
      database.type = "postgres";
      lfs.enable = true;
      secrets = {
        mailer.PASSWD = config.sops.secrets."${service.name}-smtp".path;
        database.PASSWD = config.sops.secrets."${service.name}-database".path;
      };
      dump = {
        interval = "5:00";
        type = "zip";
        file = "forgejo-backup";
        enable = true;
        backupDir = backupPath;
      };
      settings = {
        server = {
          DOMAIN = host;
          ROOT_URL = "https://${host}/";
          HTTP_PORT = service.ports.port0;
        };
        # If you need to start from scratch, don't forget to turn this off again
        service.DISABLE_REGISTRATION = true;
        actions = {
          ENABLED = true;
          DEFAULT_ACTIONS_URL = "github";
        };
        mirror = {
          ENABLED = true;
        };
        mailer = {
          ENABLED = true;
          SMTP_ADDR = instances.smtp.hostname;
          FROM = instances.smtp.email.address1;
          USER = instances.smtp.email.address1;
          PROTOCOL = "${instances.smtp.name}+${instances.smtp.records.record1}";
          SMTP_PORT = instances.smtp.ports.port1;
          SEND_AS_PLAIN_TEXT = true;
          USE_CLIENT_CERT = false;
        };
      };
    };
    caddy = {
      virtualHosts = {
        "${host}" = {
          extraConfig = ''
            reverse_proxy ${localhost}:${toString service.ports.port0}

            tls ${service.ssl.cert} ${service.ssl.key}
          '';
        };
      };
    };
  };
  sops =
    let
      sopsPath = secret: {
        path = "${service.sops.path0}/${service.name}-${secret}";
        owner = service.name;
        mode = "600";
      };
    in
    {
      secrets = builtins.listToAttrs (
        map
          (secret: {
            name = "${service.name}-${secret}";
            value = sopsPath secret;
          })
          [
            "database"
            "smtp"
          ]
      );
    };

  fileSystems."/var/lib/${service.name}" = {
    device = service.paths.path0;
    fsType = "none";
    options = [
      "bind"
    ];
    depends = [
      ceres.storage0.mount
    ];
  };

  systemd.services = {
    forgejo-dump = {
      serviceConfig = {
        ExecStartPost = "${pkgs.nushell}/bin/nu -c 'ls ${backupPath} | where name =~ forgejo-backup and modified < ((date now) - 7day) | each { rm $in.name }'";
      };
    };
  };

  systemd.tmpfiles.rules = [
    "Z ${service.paths.path0} 755 ${service.name} ${service.name} -"
    "Z ${service.sops.path0} 755 ${service.name} ${service.name} -"
  ];

  users.users.${service.name}.extraGroups = [
    caddy.name
    postgres.name
    syncthing.name
  ];

  networking = {
    firewall = {
      allowedTCPPorts = [
        service.ports.port0
      ];
    };
  };
}