dotfiles/modules/nixos/services/firefly/default.nix

{ flake, config, ... }:
let
  inherit (flake.config.people) user0;
  inherit (flake.config.people.users.${user0}) email;
  inherit (flake.config.services.instances) firefly-iii web;
  inherit (flake.config.machines.devices) ceres;
  service = firefly-iii;
  localhost = web.localhost.address0;
  host = service.domains.url0;
in
{
  services = {
    firefly-iii = {
      enable = true;
      virtualHost = "https://${host}";
      settings = {
        APP_URL = host;
        APP_KEY_FILE = config.sops.secrets."${service.name}-key".path;
        SITE_OWNER = email.address0;
        # DB_PORT = 3306;
        DB_DATABASE = "firefly";
        DB_USERNAME = "firefly";
        DB_PASSWORD_FILE = config.sops.secrets."${service.name}-pass".path;
      };
    };
    caddy = {
      virtualHosts = {
        "${host}" = {
          extraConfig = ''
            reverse_proxy ${localhost}:${toString service.ports.port0} {
                header_up X-Forwarded-Proto {scheme}
                header_up X-Forwarded-Host {host}
                header_up X-Forwarded-Server {host}
                header_up X-Forwarded-For {remote_host}
                header_up Host {host}

                timeout 300s
            }

            request_body {
                max_size 64MB
            }

            tls ${service.ssl.cert} ${service.ssl.key}
          '';
        };
      };
    };
  };

  sops =
    let
      sopsPath = secret: {
        path = "${service.sops.path0}/${service.name}-${secret}";
        owner = service.name;
        mode = "600";
      };
    in
    {
      secrets = builtins.listToAttrs (
        map
          (secret: {
            name = "${service.name}-${secret}";
            value = sopsPath secret;
          })
          [
            "key"
            "pass"
          ]
      );
    };

  fileSystems."/var/lib/${service.name}" = {
    device = service.paths.path0;
    fsType = "none";
    options = [
      "bind"
    ];
    depends = [
      ceres.storage0.mount
    ];
  };

  users.users.${service.name}.extraGroups = [
    "caddy"
  ];

  systemd.tmpfiles.rules = [
    "Z ${service.paths.path0} 755 ${service.name} ${service.name} -"
    "Z ${service.sops.path0} 755 ${service.name} ${service.name} -"
  ];

  networking = {
    firewall = {
      allowedTCPPorts = [
        service.ports.port0
      ];
    };
  };
}