dotfiles/nixos/modules/services/hledger.nix

{
  flake,
  pkgs,
  ...
}:
let
  inherit (flake.config.machines.devices)
    server
    ;
  inherit (flake.config.services.instances)
    hledger
    web
    ;
  service = hledger;
  localhost = web.localhost.address0;
  host = "${service.subdomain}.${web.domains.url0}";
in
{
  services = {
    hledger-web = {
      enable = true;
      host = localhost;
      baseUrl = "https://${host}";
      stateDir = service.paths.path0;
      port = service.ports.port0;
      journalFiles = [
        ".hledger.journal"
      ];
      allow = "edit";
    };
    caddy = {
      virtualHosts = {
        "${host}" = {
          extraConfig = ''
            redir /.well-known/carddav /remote.php/dav/ 301
            redir /.well-known/caldav /remote.php/dav/ 301

            reverse_proxy ${localhost}:${toString service.ports.port0}

            tls ${service.ssl.cert} ${service.ssl.key}
          '';
        };
      };
    };
  };

  environment = {
    systemPackages = builtins.attrValues {
      inherit (pkgs)
        hledger
        ;
    };
  };

  users = {
    users.${service.name} = {
      isSystemUser = true;
      group = service.name;
      home = service.paths.path0;
    };
    groups.${service.name} = { };
  };

  fileSystems."/var/lib/${service.name}" = {
    device = service.paths.path0;
    fsType = "none";
    options = [
      "bind"
    ];
    depends = [
      server.storage0.mount
    ];
  };

  systemd.tmpfiles.rules = [
    "Z ${service.paths.path0} 0755 ${service.name} ${service.name} -"
  ];

  networking = {
    firewall = {
      allowedTCPPorts = [
        service.ports.port0
      ];
    };
  };
}