{ config, flake, ... }:
let
  inherit (flake.config.machines.devices) ceres;
  inherit (flake.config.services.instances) opencloud web;
  service = opencloud;
  localhost = web.localhost.address0;
  host = service.domains.url0;
in
{
  services = {
    opencloud = {
      enable = true;
      url = "https://${host}";
      port = service.ports.port0;
      address = localhost;
      stateDir = "/var/lib/${service.name}";
      environmentFile = config.sops.secrets."${service.name}/env".path;
    };
    caddy = {
      virtualHosts = {
        "${host}" = {
          extraConfig = ''
            reverse_proxy https://${localhost}:${toString service.ports.port0} {
              transport http {
                tls_insecure_skip_verify
              }
            }
            tls ${service.ssl.cert} ${service.ssl.key}
          '';
        };
      };
    };
  };

  sops =
    let
      sopsPath = secret: {
        path = "${service.sops.path0}/${service.name}-${secret}";
        owner = service.name;
        mode = "600";
      };
    in
    {
      secrets = builtins.listToAttrs (
        map
          (secret: {
            name = "${service.name}/${secret}";
            value = sopsPath secret;
          })
          [
            "env"
          ]
      );
    };

  networking = {
    firewall = {
      allowedTCPPorts = [
        service.ports.port0
      ];
    };
  };
}