{
  flake,
  config,
  ...
}: let
  inherit (flake.config.people) user0 user1 user2;
  inherit (flake.config.system.device) laptop nas server;

  secrets0 = config.sops.secrets."network/synology".path;
  secrets1 = config.sops.secrets."network/server".path;
in {
  fileSystems = let
    synologyDrives = [
      "folder0"
      "folder1"
      "folder4"
    ];

    sambaDrives = [
      "samba0"
    ];

    synologyMounts = folder: {
      name = "${nas.${folder}.mount}";
      value = {
        device = nas.${folder}.device;
        fsType = "cifs";
        options = nas.${folder}.options ++ ["credentials=${secrets0}"];
      };
    };

    sambaMounts = samba: {
      name = "${server.${samba}.mount}";
      value = {
        device = server.${samba}.device;
        fsType = "cifs";
        options = server.${samba}.options ++ ["credentials=${secrets1}"];
      };
    };
  in
    {
      "/" = {
        device = "/dev/disk/by-uuid/e8a3dd5a-7b71-4d86-b157-bac5e0ba7429";
        fsType = "ext4";
      };
      "/boot" = {
        device = "/dev/disk/by-uuid/E946-BD04";
        fsType = "vfat";
        options = laptop.boot.options;
      };
    }
    // (builtins.listToAttrs (map synologyMounts synologyDrives))
    // (builtins.listToAttrs (map sambaMounts sambaDrives));

  swapDevices = [
    {device = "/dev/disk/by-uuid/7730bd62-75e2-4b6c-8dcd-f18189ee2845";}
  ];

  systemd.tmpfiles.rules = [
    "Z ${config.home-manager.users.${user0}.home.homeDirectory} 0755 ${user0} users -"
    "Z ${config.home-manager.users.${user1}.home.homeDirectory} 0755 ${user1} users -"
    "Z ${config.home-manager.users.${user2}.home.homeDirectory} 0755 ${user2} users -"
  ];

  services.udisks2.enable = true;
}