{
  flake,
  config,
  ...
}: let
  inherit (flake.config.people) user0 user1;
  inherit (flake.config.system.device) desktop server nas;
  secrets0 = config.sops.secrets."network/synology".path;
  secrets1 = config.sops.secrets."network/server".path;
in {
  fileSystems = let
    synologyDrives = [
      "folder0"
      "folder1"
      "folder2"
      "folder3"
    ];

    storageDrives = [
      "storage0"
      "storage1"
    ];

    sambaDrives = [
      "samba0"
    ];

    synologyMounts = folder: {
      name = "${nas.${folder}.mount}";
      value = {
        device = nas.${folder}.device;
        fsType = "cifs";
        options = nas.${folder}.options ++ ["credentials=${secrets0}"];
      };
    };

    storageMounts = storage: {
      name = "${desktop.${storage}.mount}";
      value = {
        device = desktop.${storage}.device;
        fsType = "ext4";
        options = desktop.${storage}.options;
      };
    };

    sambaMounts = samba: {
      name = "${server.${samba}.mount}";
      value = {
        device = server.${samba}.device;
        fsType = "cifs";
        options = server.${samba}.options ++ ["credentials=${secrets1}"];
      };
    };
  in
    {
      "/" = {
        device = "/dev/disk/by-uuid/9ea15b16-068a-4c1b-8152-096b901f1ae7";
        fsType = "ext4";
      };
      "/boot" = {
        device = "/dev/disk/by-uuid/8A33-9662";
        fsType = "vfat";
        options = desktop.boot.options;
      };
    }
    // (builtins.listToAttrs (map synologyMounts synologyDrives))
    // (builtins.listToAttrs (map storageMounts storageDrives))
    // (builtins.listToAttrs (map sambaMounts sambaDrives));

  swapDevices = [
    {device = "/dev/disk/by-uuid/b21d20df-f272-4c0c-8e7a-5effac3373f8";}
  ];

  systemd.tmpfiles.rules = [
    "Z ${config.home-manager.users.${user0}.home.homeDirectory} 0755 ${user0} users -"
    "Z ${config.home-manager.users.${user1}.home.homeDirectory} 0755 ${user1} users -"
    "Z ${desktop.storage0.mount} 0755 ${user0} users -"
    "Z ${desktop.storage1.mount} 0755 ${user0} users -"
  ];

  services.udisks2.enable = true;
}