{
  flake,
  ...
}:
let
  inherit (flake.config.people) user0;
  inherit (flake.config.services) instances;
  serviceCfg = instances.forgejo;
  smtpCfg = instances.smtp;
in
{
  forgejoVM =
    {
      user,
      ip,
      mac,
      userMac,
      ssh,
      mnt,
      host,
    }:
    {
      microvm.vms = {
        "${serviceCfg.name}-${user}" = {
          autostart = true;
          restartIfChanged = true;
          config = {
            system.stateVersion = "24.05";
            time.timeZone = "America/Winnipeg";
            users.users.root.openssh.authorizedKeys.keys = flake.config.people.users.${user0}.sshKeys;
            services = {
              ${serviceCfg.name} = {
                enable = true;
                lfs.enable = true;
                secrets = {
                  mailer.PASSWD = "/run/secrets/${user}-smtp";
                };
                settings = {
                  server = {
                    DOMAIN = host;
                    ROOT_URL = "https://${host}/";
                    HTTP_PORT = serviceCfg.ports.port0;
                  };
                  # If you need to start from scratch, don't forget to turn this off again
                  service.DISABLE_REGISTRATION = true;
                  actions = {
                    ENABLED = true;
                    DEFAULT_ACTIONS_URL = "github";
                  };
                  mirror = {
                    ENABLED = true;
                  };
                  mailer = {
                    ENABLED = true;
                    SMTP_ADDR = smtpCfg.interface.interface1.domain;
                    FROM = smtpCfg.interfaces.interface1.email;
                    USER = smtpCfg.interfaces.interface1.email;
                    PROTOCOL = "smtp+starttls";
                    SMTP_PORT = smtpCfg.ports.port1;
                    SEND_AS_PLAIN_TEXT = true;
                    USE_CLIENT_CERT = false;
                  };
                };
              };
              openssh = {
                enable = true;
                settings = {
                  PasswordAuthentication = false;
                  PermitRootLogin = "prohibit-password";
                };
              };
            };
            networking.firewall.allowedTCPPorts = [
              22 # SSH
              25 # SMTP
              139 # SMTP
              2525 # SMTP
              smtpCfg.ports.port0
              serviceCfg.ports.port0
            ];
            fileSystems."/tmp" = {
              device = "tmpfs";
              fsType = "tmpfs";
              options = [
                "size=4G"
                "mode=1777"
              ];
            };
            systemd = {
              network = {
                enable = true;
                networks."20-lan" = {
                  matchConfig.Name = "enp0s5";
                  addresses = [ { Address = "${ip}/24"; } ];
                  routes = [
                    {
                      Destination = "0.0.0.0/0";
                      Gateway = "192.168.50.1";
                    }
                  ];
                  dns = [
                    "1.1.1.1"
                    "8.8.8.8"
                  ];
                };
              };
              tmpfiles.rules = [
                "d /var/lib/${serviceCfg.name} 0755 ${serviceCfg.name} ${serviceCfg.name} -"
              ];
            };
            systemd.services.systemd-networkd.wantedBy = [ "multi-user.target" ];
            microvm = {
              vcpu = 1;
              mem = 1024;
              hypervisor = "qemu";
              interfaces = [
                {
                  type = "tap";
                  id = "vm-fg-${user}";
                  mac = mac;
                }
                {
                  type = "user";
                  id = "vmuser-cloud";
                  mac = userMac;
                }
              ];
              forwardPorts = [
                {
                  from = "host";
                  host.port = ssh;
                  guest.port = 22;
                }
              ];
              shares = [
                {
                  mountPoint = "/nix/.ro-store";
                  proto = "virtiofs";
                  source = "/nix/store";
                  tag = "read_only_nix_store";
                }
                {
                  mountPoint = "/var/lib/${serviceCfg.name}";
                  proto = "virtiofs";
                  source = "${mnt}/${serviceCfg.name}";
                  tag = "${serviceCfg.name}_${user}_data";
                }
                {
                  mountPoint = "/run/secrets";
                  proto = "virtiofs";
                  source = "/run/secrets/${serviceCfg.name}";
                  tag = "host_secrets";
                }
              ];
            };
          };
        };
      };

      systemd.tmpfiles.rules = [
        "d ${mnt}/${serviceCfg.name} 0751 microvm wheel - -"
      ];
      sops.secrets = {
        "${serviceCfg.name}/${user}-smtp" = {
          owner = "root";
          mode = "0600";
        };
      };
    };
}