feat: init

systems/laptop/boot.nix

@@ -0,0 +1,28 @@
+{
+  pkgs,
+  config,
+  ...
+}: {
+  boot = {
+    extraModulePackages = [
+      config.boot.kernelPackages.v4l2loopback.out
+    ];
+    supportedFilesystems = ["ntfs"];
+    initrd = {
+      availableKernelModules = ["nvme" "ahci" "xhci_pci" "usb_storage" "usbhid" "sd_mod"];
+      kernelModules = [];
+    };
+
+    kernelModules = ["kvm-amd" "vfio-pci" "v4l2loopback"];
+
+    kernelPackages = pkgs.linuxPackages_latest;
+
+    loader = {
+      efi = {
+        canTouchEfiVariables = true;
+        efiSysMountPoint = "/boot";
+      };
+      systemd-boot.enable = true;
+    };
+  };
+}

systems/laptop/default.nix

@@ -0,0 +1,13 @@
+{lib, ...}: {
+  imports = [
+    ./boot.nix
+    ./filesystem.nix
+    ./graphics.nix
+    ./hardware.nix
+    ./networking.nix
+    ./sops.nix
+    ./ssh.nix
+  ];
+  nixpkgs.hostPlatform = lib.mkForce "x86_64-linux";
+  system.stateVersion = lib.mkForce "24.05";
+}

systems/laptop/filesystem.nix

@@ -0,0 +1,66 @@
+{
+  flake,
+  config,
+  ...
+}: let
+  inherit (flake.config.people) user0 user1 user2;
+  inherit (flake.config.system.device) laptop nas server;
+
+  secrets0 = config.sops.secrets."network/synology".path;
+  secrets1 = config.sops.secrets."network/server".path;
+in {
+  fileSystems = let
+    synologyDrives = [
+      "folder0"
+      "folder1"
+      "folder4"
+    ];
+
+    sambaDrives = [
+      "samba0"
+    ];
+
+    synologyMounts = folder: {
+      name = "${nas.${folder}.mount}";
+      value = {
+        device = nas.${folder}.device;
+        fsType = "cifs";
+        options = nas.${folder}.options ++ ["credentials=${secrets0}"];
+      };
+    };
+
+    sambaMounts = samba: {
+      name = "${server.${samba}.mount}";
+      value = {
+        device = server.${samba}.device;
+        fsType = "cifs";
+        options = server.${samba}.options ++ ["credentials=${secrets1}"];
+      };
+    };
+  in
+    {
+      "/" = {
+        device = "/dev/disk/by-uuid/e8a3dd5a-7b71-4d86-b157-bac5e0ba7429";
+        fsType = "ext4";
+      };
+      "/boot" = {
+        device = "/dev/disk/by-uuid/E946-BD04";
+        fsType = "vfat";
+        options = laptop.boot.options;
+      };
+    }
+    // (builtins.listToAttrs (map synologyMounts synologyDrives))
+    // (builtins.listToAttrs (map sambaMounts sambaDrives));
+
+  swapDevices = [
+    {device = "/dev/disk/by-uuid/7730bd62-75e2-4b6c-8dcd-f18189ee2845";}
+  ];
+
+  systemd.tmpfiles.rules = [
+    "Z ${config.home-manager.users.${user0}.home.homeDirectory} 0755 ${user0} users -"
+    "Z ${config.home-manager.users.${user1}.home.homeDirectory} 0755 ${user1} users -"
+    "Z ${config.home-manager.users.${user2}.home.homeDirectory} 0755 ${user2} users -"
+  ];
+
+  services.udisks2.enable = true;
+}

systems/laptop/graphics.nix

@@ -0,0 +1,17 @@
+{pkgs, ...}: {
+  hardware = {
+    graphics = {
+      enable = true;
+      extraPackages = with pkgs; [
+        rocm-opencl-icd
+        rocm-opencl-runtime
+        rocmPackages.clr.icd
+        pkgs.amdvlk
+      ];
+      extraPackages32 = [
+        pkgs.driversi686Linux.amdvlk
+      ];
+    };
+  };
+  boot.initrd.kernelModules = ["amdgpu"];
+}

systems/laptop/hardware.nix

@@ -0,0 +1,12 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}: {
+  hardware = {
+    firmware = [pkgs.rtl8761b-firmware];
+    enableAllFirmware = true;
+    cpu.amd.updateMicrocode = lib.mkDefault config.hardware.enableRedistributableFirmware;
+  };
+}

systems/laptop/networking.nix

@@ -0,0 +1,28 @@
+{
+  lib,
+  flake,
+  ...
+}: let
+  inherit (flake.config.system.device) laptop;
+in {
+  networking = {
+    hostName = laptop.name;
+    networkmanager.enable = true;
+    useDHCP = lib.mkDefault true;
+    firewall = {
+      enable = true;
+    };
+  };
+  services = {
+    avahi = {
+      enable = true;
+      openFirewall = true;
+      nssmdns4 = true;
+    };
+    sshd.enable = true;
+    openssh = {
+      enable = true;
+      settings.PasswordAuthentication = false;
+    };
+  };
+}

systems/laptop/sops.nix

@@ -0,0 +1,41 @@
+{flake, ...}: let
+  inherit
+    (flake.config.people)
+    user0
+    user1
+    ;
+in {
+  sops = {
+    defaultSopsFile = ../../secrets/secrets.yaml;
+    validateSopsFiles = false;
+    age = {
+      keyFile = "/var/lib/sops-nix/key.txt";
+      generateKey = false;
+    };
+    secrets = {
+      "ssh/private" = {
+        path = "/home/${user0}/.ssh/id_ed25519";
+        owner = user0;
+      };
+      "ssh/public" = {
+        path = "/home/${user0}/.ssh/id_ed25519.pub";
+        owner = user0;
+      };
+      "network/synology" = {
+        path = "/var/lib/secrets/synology";
+        owner = "root";
+        mode = "600";
+      };
+      "network/server" = {
+        path = "/var/lib/secrets/server";
+        owner = "root";
+        mode = "600";
+      };
+      "network/${user1}" = {
+        path = "/var/lib/secrets/${user1}";
+        owner = "root";
+        mode = "600";
+      };
+    };
+  };
+}

systems/laptop/ssh.nix

@@ -0,0 +1,8 @@
+{flake, ...}: let
+  inherit (flake.config.people) user0;
+  inherit (flake.config.people.user.${user0}) sshKeys;
+in {
+  users.users.${user0} = {
+    openssh.authorizedKeys.keys = sshKeys;
+  };
+}