feat: init

systems/desktop/boot.nix

@@ -0,0 +1,29 @@
+{
+  pkgs,
+  config,
+  ...
+}: {
+  boot = {
+    extraModulePackages = [
+      config.boot.kernelPackages.v4l2loopback.out
+    ];
+    supportedFilesystems = ["ntfs"];
+    initrd = {
+      network.openvpn.enable = true;
+      availableKernelModules = ["nvme" "ahci" "xhci_pci" "usb_storage" "usbhid" "sd_mod"];
+      kernelModules = [];
+    };
+
+    kernelModules = ["kvm-amd" "vfio-pci" "v4l2loopback"];
+
+    kernelPackages = pkgs.linuxPackages_latest;
+
+    loader = {
+      efi = {
+        canTouchEfiVariables = true;
+        efiSysMountPoint = "/boot";
+      };
+      systemd-boot.enable = true;
+    };
+  };
+}

systems/desktop/default.nix

@@ -0,0 +1,13 @@
+{lib, ...}: {
+  imports = [
+    ./boot.nix
+    ./filesystem.nix
+    ./graphics.nix
+    ./hardware.nix
+    ./networking.nix
+    ./sops.nix
+    ./ssh.nix
+  ];
+  nixpkgs.hostPlatform = lib.mkForce "x86_64-linux";
+  system.stateVersion = lib.mkForce "24.05";
+}

systems/desktop/filesystem.nix

@@ -0,0 +1,82 @@
+{
+  flake,
+  config,
+  ...
+}: let
+  inherit (flake.config.people) user0 user1;
+  inherit (flake.config.system.device) desktop server nas;
+  secrets0 = config.sops.secrets."network/synology".path;
+  secrets1 = config.sops.secrets."network/server".path;
+in {
+  fileSystems = let
+    synologyDrives = [
+      "folder0"
+      "folder1"
+      "folder2"
+      "folder3"
+    ];
+
+    storageDrives = [
+      "storage0"
+      "storage1"
+    ];
+
+    sambaDrives = [
+      "samba0"
+    ];
+
+    synologyMounts = folder: {
+      name = "${nas.${folder}.mount}";
+      value = {
+        device = nas.${folder}.device;
+        fsType = "cifs";
+        options = nas.${folder}.options ++ ["credentials=${secrets0}"];
+      };
+    };
+
+    storageMounts = storage: {
+      name = "${desktop.${storage}.mount}";
+      value = {
+        device = desktop.${storage}.device;
+        fsType = "ext4";
+        options = desktop.${storage}.options;
+      };
+    };
+
+    sambaMounts = samba: {
+      name = "${server.${samba}.mount}";
+      value = {
+        device = server.${samba}.device;
+        fsType = "cifs";
+        options = server.${samba}.options ++ ["credentials=${secrets1}"];
+      };
+    };
+  in
+    {
+      "/" = {
+        device = "/dev/disk/by-uuid/9ea15b16-068a-4c1b-8152-096b901f1ae7";
+        fsType = "ext4";
+      };
+      "/boot" = {
+        device = "/dev/disk/by-uuid/8A33-9662";
+        fsType = "vfat";
+        options = desktop.boot.options;
+      };
+    }
+    // (builtins.listToAttrs (map synologyMounts synologyDrives))
+    // (builtins.listToAttrs (map storageMounts storageDrives))
+    // (builtins.listToAttrs (map sambaMounts sambaDrives));
+
+  swapDevices = [
+    {device = "/dev/disk/by-uuid/b21d20df-f272-4c0c-8e7a-5effac3373f8";}
+  ];
+
+  systemd.tmpfiles.rules = [
+    "Z ${config.home-manager.users.${user0}.home.homeDirectory} 0755 ${user0} users -"
+    "Z ${config.home-manager.users.${user1}.home.homeDirectory} 0755 ${user1} users -"
+    "Z ${desktop.storage0.mount} 0755 ${user0} users -"
+    "Z ${desktop.storage1.mount} 0755 ${user0} users -"
+  ];
+
+  services.udisks2.enable = true;
+}

systems/desktop/graphics.nix

@@ -0,0 +1,18 @@
+{pkgs, ...}: {
+  hardware = {
+    graphics = {
+      enable = true;
+
+      extraPackages = with pkgs; [
+        rocm-opencl-icd
+        rocm-opencl-runtime
+        rocmPackages.clr.icd
+        pkgs.amdvlk
+      ];
+      extraPackages32 = [
+        pkgs.driversi686Linux.amdvlk
+      ];
+    };
+  };
+  boot.initrd.kernelModules = ["amdgpu"];
+}

systems/desktop/hardware.nix

@@ -0,0 +1,13 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}: {
+  hardware = {
+    firmware = [pkgs.rtl8761b-firmware];
+    enableAllFirmware = true;
+    ledger.enable = true;
+    cpu.amd.updateMicrocode = lib.mkDefault config.hardware.enableRedistributableFirmware;
+  };
+}

systems/desktop/networking.nix

@@ -0,0 +1,33 @@
+{
+  lib,
+  flake,
+  ...
+}: let
+  inherit (flake.config.system.device) desktop;
+in {
+  networking = {
+    hostName = desktop.name;
+    networkmanager.enable = true;
+    useDHCP = lib.mkDefault true;
+    firewall = {
+      enable = true;
+      allowedTCPPorts = [
+        22 # SSH
+        4333 # Feishin
+        2234 # Soulseek
+      ];
+    };
+  };
+  services = {
+    avahi = {
+      enable = true;
+      openFirewall = true;
+      nssmdns4 = true;
+    };
+    sshd.enable = true;
+    openssh = {
+      enable = true;
+      settings.PasswordAuthentication = false;
+    };
+  };
+}

systems/desktop/sops.nix

@@ -0,0 +1,41 @@
+{flake, ...}: let
+  inherit (flake.config.people) user0;
+  inherit (flake.config.people.user.${user0}) git;
+in {
+  sops = {
+    defaultSopsFile = ../../secrets/secrets.yaml;
+    validateSopsFiles = false;
+    age = {
+      keyFile = "/var/lib/sops-nix/key.txt";
+      generateKey = false;
+    };
+    secrets = {
+      "ssh/private" = {
+        path = "/home/${user0}/.ssh/id_ed25519";
+        owner = user0;
+      };
+      "ssh/public" = {
+        path = "/home/${user0}/.ssh/id_ed25519.pub";
+        owner = user0;
+      };
+      "ssh/hosts" = {
+        path = "/home/${user0}/.ssh/known_hosts";
+        owner = user0;
+      };
+      "network/synology" = {
+        path = "/var/lib/secrets/synology";
+        owner = "root";
+        mode = "600";
+      };
+      "network/server" = {
+        path = "/var/lib/secrets/server";
+        owner = "root";
+        mode = "600";
+      };
+      "discord-token" = {
+        path = "${git.path0}/zookeeper/.env";
+        owner = user0;
+      };
+    };
+  };
+}

systems/desktop/ssh.nix

@@ -0,0 +1,8 @@
+{flake, ...}: let
+  inherit (flake.config.people) user0;
+  inherit (flake.config.people.user.${user0}) sshKeys;
+in {
+  users.users.${user0} = {
+    openssh.authorizedKeys.keys = sshKeys;
+  };
+}