feat: changed naming convention for devices

systems/jupiter/config/boot.nix

@@ -0,0 +1,44 @@
+{
+  pkgs,
+  config,
+  ...
+}:
+{
+  boot = {
+    extraModulePackages = [
+      config.boot.kernelPackages.v4l2loopback.out
+    ];
+    supportedFilesystems = [
+      "ntfs"
+    ];
+    initrd = {
+      network.openvpn.enable = true;
+      availableKernelModules = [
+        "nvme"
+        "ahci"
+        "xhci_pci"
+        "usb_storage"
+        "usbhid"
+        "sd_mod"
+      ];
+      kernelModules = [
+      ];
+    };
+
+    kernelModules = [
+      "kvm-amd"
+      "vfio-pci"
+      "v4l2loopback"
+    ];
+
+    kernelPackages = pkgs.linuxPackages_latest;
+
+    loader = {
+      efi = {
+        canTouchEfiVariables = true;
+        efiSysMountPoint = "/boot";
+      };
+      systemd-boot.enable = true;
+    };
+  };
+}

systems/jupiter/config/filesystem.nix

@@ -0,0 +1,99 @@
+{
+  flake,
+  config,
+  ...
+}:
+let
+  inherit (flake.config.people)
+    user0
+    user1
+    ;
+  inherit (flake.config.machines.devices)
+    jupiter
+    ceres
+    synology
+    ;
+  inherit (flake.config.services.instances)
+    samba
+    ;
+
+  synologySecrets = config.sops.secrets."network/synology".path;
+  ceresSecrets = config.sops.secrets."network/server".path;
+in
+{
+  fileSystems =
+    let
+      synologyDrives = [
+        "folder0"
+        "folder1"
+        "folder2"
+      ];
+
+      storageDrives = [
+        "storage0"
+        "storage1"
+      ];
+
+      sambaDrives = [
+        "samba0"
+      ];
+
+      synologyMounts = synologyDrive: {
+        name = "${synology.${synologyDrive}.mount}";
+        value = {
+          device = synology.${synologyDrive}.device;
+          fsType = "cifs";
+          options = synology.${synologyDrive}.options ++ [
+            "credentials=${synologySecrets}"
+          ];
+        };
+      };
+
+      storageMounts = storageDrive: {
+        name = "${jupiter.${storageDrive}.mount}";
+        value = {
+          device = jupiter.${storageDrive}.device;
+          fsType = "ext4";
+          options = jupiter.${storageDrive}.options;
+        };
+      };
+
+      sambaMounts = sambaDrive: {
+        name = "${ceres.${sambaDrive}.mount}/${samba.paths.path1}";
+        value = {
+          device = "${ceres.${sambaDrive}.device}/${samba.paths.path1}";
+          fsType = "cifs";
+          options = ceres.${sambaDrive}.options ++ [
+            "credentials=${ceresSecrets}"
+          ];
+        };
+      };
+    in
+    {
+      "/" = {
+        device = "/dev/disk/by-uuid/abf85775-d233-4303-ad03-652137d0fa6f";
+        fsType = "ext4";
+      };
+      "/boot" = {
+        device = "/dev/disk/by-uuid/73E2-4DC1";
+        fsType = "vfat";
+        options = jupiter.boot.options;
+      };
+    }
+    // (builtins.listToAttrs (map synologyMounts synologyDrives))
+    // (builtins.listToAttrs (map storageMounts storageDrives))
+    // (builtins.listToAttrs (map sambaMounts sambaDrives));
+
+  swapDevices = [
+    { device = "/dev/disk/by-uuid/1a8c0107-315e-427a-bc82-9e73dc3bf8f3"; }
+  ];
+
+  systemd.tmpfiles.rules = [
+    "Z ${config.home-manager.users.${user0}.home.homeDirectory} 0755 ${user0} users -"
+    "Z ${config.home-manager.users.${user1}.home.homeDirectory} 0755 ${user1} users -"
+    "Z ${jupiter.storage0.mount} 0755 ${user0} users -"
+    "Z ${jupiter.storage1.mount} 0755 ${user0} users -"
+  ];
+
+  services.udisks2.enable = true;
+}

systems/jupiter/config/graphics.nix

@@ -0,0 +1,25 @@
+{ pkgs, ... }:
+{
+  hardware = {
+    graphics = {
+      enable = true;
+      enable32Bit = true;
+      extraPackages = builtins.attrValues {
+        # inherit (pkgs)
+        #   amdvlk
+        #   ;
+        inherit (pkgs.rocmPackages.clr)
+          icd
+          ;
+      };
+      # extraPackages32 = builtins.attrValues {
+      #   inherit (pkgs.driversi686Linux)
+      #     amdvlk
+      #     ;
+      # };
+    };
+  };
+  boot.initrd.kernelModules = [
+    "amdgpu"
+  ];
+}

systems/jupiter/config/hardware.nix

@@ -0,0 +1,18 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+{
+  hardware = {
+    firmware = builtins.attrValues {
+      inherit (pkgs)
+        rtl8761b-firmware
+        ;
+    };
+    enableAllFirmware = true;
+    ledger.enable = true;
+    cpu.amd.updateMicrocode = lib.mkDefault config.hardware.enableRedistributableFirmware;
+  };
+}

systems/jupiter/config/networking.nix

@@ -0,0 +1,41 @@
+{
+  lib,
+  flake,
+  ...
+}:
+let
+  inherit (flake.config.machines.devices)
+    jupiter
+    ;
+in
+{
+  networking = {
+    hostName = jupiter.name;
+    networkmanager.enable = true;
+    nftables.enable = true;
+    useDHCP = lib.mkDefault true;
+    firewall = {
+      enable = true;
+      allowedTCPPorts = [
+        22 # SSH
+        4333 # Feishin
+        2234 # Soulseek
+        3131 # Deskreen
+        1234 # Elm-land server
+        55473
+      ];
+    };
+  };
+  services = {
+    avahi = {
+      enable = true;
+      openFirewall = true;
+      nssmdns4 = true;
+    };
+    sshd.enable = true;
+    openssh = {
+      enable = true;
+      settings.PasswordAuthentication = false;
+    };
+  };
+}

systems/jupiter/config/sops.nix

@@ -0,0 +1,29 @@
+{ flake, ... }:
+let
+  inherit (flake.config.people)
+    user0
+    ;
+  inherit (flake.config.people.users.${user0})
+    paths
+    ;
+in
+{
+  sops = {
+    secrets = {
+      "network/synology" = {
+        path = "/var/lib/secrets/synology";
+        owner = "root";
+        mode = "600";
+      };
+      "network/server" = {
+        path = "/var/lib/secrets/server";
+        owner = "root";
+        mode = "600";
+      };
+      "discord-token" = {
+        path = "${paths.path0}/zookeeper/.env";
+        owner = user0;
+      };
+    };
+  };
+}

systems/jupiter/default.nix

@@ -0,0 +1,17 @@
+{ lib, ... }:
+let
+  configPath = ./config;
+
+  jupiterImports =
+    let
+      files = builtins.attrNames (builtins.readDir configPath);
+    in
+    map (name: configPath + "/${name}") (
+      builtins.filter (name: builtins.match ".*\\.nix$" name != null) files
+    );
+in
+{
+  imports = jupiterImports;
+  nixpkgs.hostPlatform = lib.mkForce "x86_64-linux";
+  system.stateVersion = lib.mkForce "24.05";
+}