chore: init

systems/mars/config/boot.nix

@@ -0,0 +1,44 @@
+{
+  pkgs,
+  config,
+  ...
+}:
+{
+  boot = {
+    extraModulePackages = [
+      config.boot.kernelPackages.v4l2loopback.out
+    ];
+    supportedFilesystems = [
+      "ntfs"
+    ];
+    initrd = {
+      network.openvpn.enable = true;
+      availableKernelModules = [
+        "nvme"
+        "ahci"
+        "xhci_pci"
+        "usb_storage"
+        "usbhid"
+        "sd_mod"
+      ];
+      kernelModules = [
+      ];
+    };
+
+    kernelModules = [
+      "kvm-amd"
+      "vfio-pci"
+      "v4l2loopback"
+    ];
+
+    kernelPackages = pkgs.linuxPackages_latest;
+
+    loader = {
+      efi = {
+        canTouchEfiVariables = true;
+        efiSysMountPoint = "/boot";
+      };
+      systemd-boot.enable = true;
+    };
+  };
+}

systems/mars/config/filesystem.nix

@@ -0,0 +1,96 @@
+{
+  flake,
+  config,
+  ...
+}:
+let
+  inherit (flake.config.people) user0 user1;
+  inherit (flake.config.machines.devices) mars ceres synology;
+  inherit (flake.config.services.instances) jellyfin audiobookshelf comfyui;
+  synologySecrets = config.sops.secrets."network/synology".path;
+  ceresSecrets = config.sops.secrets."network/server".path;
+in
+{
+  fileSystems =
+    let
+      synologyDrives = [
+        "folder0"
+        "folder1"
+      ];
+
+      storageDrives = [
+        "storage0"
+        "storage1"
+      ];
+
+      sambaDrives = [
+        "samba0"
+      ];
+
+      sambaFolders = [
+        audiobookshelf.name
+        jellyfin.name
+        comfyui.name
+      ];
+
+      synologyMounts = synologyDrive: {
+        name = "${synology.${synologyDrive}.mount}";
+        value = {
+          device = synology.${synologyDrive}.device;
+          fsType = "cifs";
+          options = synology.${synologyDrive}.options ++ [
+            "credentials=${synologySecrets}"
+          ];
+        };
+      };
+
+      storageMounts = storageDrive: {
+        name = "${mars.${storageDrive}.mount}";
+        value = {
+          device = mars.${storageDrive}.device;
+          fsType = "ext4";
+          options = mars.${storageDrive}.options;
+        };
+      };
+
+      sambaMounts = sambaDrive: folder: {
+        name = "${ceres.${sambaDrive}.mount}/${folder}";
+        value = {
+          device = "${ceres.${sambaDrive}.device}/${folder}";
+          fsType = "cifs";
+          options = ceres.${sambaDrive}.options ++ [
+            "credentials=${ceresSecrets}"
+          ];
+        };
+      };
+    in
+    {
+      "/" = {
+        device = "/dev/disk/by-uuid/cca4aaac-9f98-42a5-8bcc-81c7048aad84";
+        fsType = "ext4";
+      };
+      "/boot" = {
+        device = "/dev/disk/by-uuid/7199-F75B";
+        fsType = "vfat";
+        options = mars.boot.options;
+      };
+    }
+    // (builtins.listToAttrs (map synologyMounts synologyDrives))
+    // (builtins.listToAttrs (map storageMounts storageDrives))
+    // (builtins.listToAttrs (
+      builtins.concatMap (drive: map (folder: sambaMounts drive folder) sambaFolders) sambaDrives
+    ));
+
+  swapDevices = [
+    { device = "/dev/disk/by-uuid/d9c787ac-9f10-41a4-8702-242922f44056"; }
+  ];
+
+  systemd.tmpfiles.rules = [
+    "Z ${config.home-manager.users.${user0}.home.homeDirectory} 0755 ${user0} users -"
+    "Z ${config.home-manager.users.${user1}.home.homeDirectory} 0755 ${user1} users -"
+    "Z ${mars.storage0.mount} 0755 ${user0} users -"
+    "Z ${mars.storage1.mount} 0755 ${user0} users -"
+  ];
+
+  services.udisks2.enable = true;
+}

systems/mars/config/graphics.nix

@@ -0,0 +1,29 @@
+{ pkgs, ... }:
+{
+  hardware = {
+    amdgpu.overdrive = {
+      enable = true;
+      ppfeaturemask = "0xffffffff";
+    };
+    graphics = {
+      enable = true;
+      enable32Bit = true;
+      extraPackages = builtins.attrValues {
+        inherit (pkgs)
+          amdvlk
+          ;
+        inherit (pkgs.rocmPackages.clr)
+          icd
+          ;
+      };
+      extraPackages32 = builtins.attrValues {
+        inherit (pkgs.driversi686Linux)
+          amdvlk
+          ;
+      };
+    };
+  };
+  boot.initrd.kernelModules = [
+    "amdgpu"
+  ];
+}

systems/mars/config/hardware.nix

@@ -0,0 +1,18 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+{
+  hardware = {
+    firmware = builtins.attrValues {
+      inherit (pkgs)
+        rtl8761b-firmware
+        ;
+    };
+    enableAllFirmware = true;
+    ledger.enable = true;
+    cpu.amd.updateMicrocode = lib.mkDefault config.hardware.enableRedistributableFirmware;
+  };
+}

systems/mars/config/networking.nix

@@ -0,0 +1,42 @@
+{
+  lib,
+  flake,
+  ...
+}:
+let
+  inherit (flake.config.machines.devices)
+    mars
+    ;
+in
+{
+  networking = {
+    hostName = mars.name;
+    networkmanager.enable = true;
+    nftables.enable = true;
+    useDHCP = lib.mkDefault true;
+    firewall = {
+      enable = true;
+      allowedTCPPorts = [
+        22 # SSH
+        4333 # Feishin
+        2234 # Soulseek
+        3131 # Deskreen
+        1234 # Elm-land server
+        5037 # ADB Server
+        37751
+      ];
+    };
+  };
+  services = {
+    avahi = {
+      enable = true;
+      openFirewall = true;
+      nssmdns4 = true;
+    };
+    sshd.enable = true;
+    openssh = {
+      enable = true;
+      settings.PasswordAuthentication = false;
+    };
+  };
+}

systems/mars/config/sops.nix

@@ -0,0 +1,29 @@
+{ flake, ... }:
+let
+  inherit (flake.config.people)
+    user0
+    ;
+  inherit (flake.config.people.users.${user0})
+    paths
+    ;
+in
+{
+  sops = {
+    secrets = {
+      "network/synology" = {
+        path = "/var/lib/secrets/synology";
+        owner = "root";
+        mode = "600";
+      };
+      "network/server" = {
+        path = "/var/lib/secrets/server";
+        owner = "root";
+        mode = "600";
+      };
+      "discord-token" = {
+        path = "${paths.path0}/zookeeper/.env";
+        owner = user0;
+      };
+    };
+  };
+}

systems/mars/config/wireguard.nix

@@ -0,0 +1,38 @@
+{ config, flake, ... }:
+let
+  inherit (flake.config.services.instances) wireGuard;
+  inherit (flake.config.machines.devices) mars;
+  service = wireGuard;
+in
+{
+  networking = {
+    wireguard.interfaces = {
+      wg0 = {
+        ips = [ "${mars.wireguard.ip0}/32" ];
+        privateKeyFile = config.sops.secrets."${service.name}-mars-private".path;
+      };
+    };
+  };
+
+  sops =
+    let
+      sopsPath = secret: {
+        path = "${service.sops.path0}/${service.name}-${secret}-pass";
+        owner = "root";
+        mode = "600";
+      };
+    in
+    {
+      secrets = builtins.listToAttrs (
+        map
+          (secret: {
+            name = "${service.name}-${secret}";
+            value = sopsPath secret;
+          })
+          [
+            "mars-private"
+            "mars-public"
+          ]
+      );
+    };
+}

systems/mars/default.nix

@@ -0,0 +1,17 @@
+{ lib, ... }:
+let
+  configPath = ./config;
+
+  marsImports =
+    let
+      files = builtins.attrNames (builtins.readDir configPath);
+    in
+    map (name: configPath + "/${name}") (
+      builtins.filter (name: builtins.match ".*\\.nix$" name != null) files
+    );
+in
+{
+  imports = marsImports;
+  nixpkgs.hostPlatform = lib.mkForce "x86_64-linux";
+  system.stateVersion = lib.mkForce "24.05";
+}