chore: init

systems/ceres/config/boot.nix

@@ -0,0 +1,43 @@
+{
+  pkgs,
+  config,
+  ...
+}:
+{
+  boot = {
+    extraModulePackages = [
+      config.boot.kernelPackages.v4l2loopback.out
+    ];
+    supportedFilesystems = [
+      "ntfs"
+    ];
+    initrd = {
+      availableKernelModules = [
+        "nvme"
+        "ahci"
+        "xhci_pci"
+        "usb_storage"
+        "usbhid"
+        "sd_mod"
+      ];
+      kernelModules = [
+      ];
+    };
+
+    kernelModules = [
+      "kvm-amd"
+      "vfio-pci"
+      "v4l2loopback"
+    ];
+
+    kernelPackages = pkgs.linuxPackages_latest;
+
+    loader = {
+      efi = {
+        canTouchEfiVariables = true;
+        efiSysMountPoint = "/boot";
+      };
+      systemd-boot.enable = true;
+    };
+  };
+}

systems/ceres/config/filesystem.nix

@@ -0,0 +1,52 @@
+{
+  flake,
+  config,
+  ...
+}:
+let
+  inherit (flake.config.people)
+    user0
+    ;
+  inherit (flake.config.machines.devices)
+    ceres
+    ;
+in
+{
+  fileSystems =
+    let
+      storageDrives = [
+        "storage0"
+      ];
+
+      storageMounts = storage: {
+        name = "${ceres.${storage}.mount}";
+        value = {
+          device = ceres.${storage}.device;
+          fsType = "ext4";
+          options = ceres.${storage}.options;
+        };
+      };
+    in
+    {
+      "/" = {
+        device = "/dev/disk/by-uuid/de4e681b-0667-4bf8-8d6e-c50894aa41cd";
+        fsType = "ext4";
+      };
+      "/boot" = {
+        device = "/dev/disk/by-uuid/C68D-B1C0";
+        fsType = "vfat";
+      };
+    }
+    // (builtins.listToAttrs (map storageMounts storageDrives));
+
+  swapDevices = [
+    { device = "/dev/disk/by-uuid/259fcc06-912c-4bd3-b781-8f77449e935a"; }
+  ];
+
+  systemd.tmpfiles.rules = [
+    "Z ${config.home-manager.users.${user0}.home.homeDirectory} 0755 ${user0} users -"
+    "Z ${ceres.storage0.mount} 2775 root root -"
+  ];
+
+  services.udisks2.enable = true;
+}

systems/ceres/config/graphics.nix

@@ -0,0 +1,61 @@
+{
+  pkgs,
+  config,
+  lib,
+  ...
+}:
+{
+  environment = {
+    etc."libva.conf".text = ''
+      LIBVA_MESSAGING_LEVEL=1
+    '';
+    systemPackages = builtins.attrValues {
+      inherit (pkgs) ddcutil;
+      # Remove CUDA from system packages for now
+      # inherit (pkgs.cudaPackages) cudatoolkit;
+    };
+    sessionVariables = {
+      MOZ_DISABLE_RDD_SANDBOX = 1;
+      LIBVA_DRIVER_NAME = "nvidia";
+    };
+    variables = {
+      GBM_BACKEND = "nvidia-drm";
+      __GLX_VENDOR_LIBRARY_NAME = "nvidia";
+      NIZOS_OZONE_WL = "1";
+      KWIN_DRM_ALLOW_NVIDIA_COLORSPACE = "1";
+      ENABLE_HDR_WSI = "1";
+    };
+  };
+
+  hardware = {
+    graphics = {
+      enable = true;
+      enable32Bit = true;
+      extraPackages = builtins.attrValues { inherit (pkgs) nvidia-vaapi-driver vaapiVdpau; };
+      extraPackages32 = builtins.attrValues {
+        inherit (pkgs.pkgsi686Linux) nvidia-vaapi-driver vaapiVdpau;
+      };
+    };
+    nvidia = {
+      modesetting.enable = true;
+      forceFullCompositionPipeline = false;
+      nvidiaSettings = true;
+      open = true;
+      gsp.enable = true;
+      package = config.boot.kernelPackages.nvidiaPackages.latest;
+      powerManagement = {
+        enable = true;
+        finegrained = false;
+      };
+    };
+  };
+
+  services = {
+    xserver = {
+      enable = true;
+      videoDrivers = [ "nvidia" ];
+    };
+  };
+
+  hardware.nvidia-container-toolkit.enable = lib.mkIf config.virtualisation.docker.enable true;
+}

systems/ceres/config/hardware.nix

@@ -0,0 +1,15 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+{
+  hardware = {
+    firmware = [
+      pkgs.rtl8761b-firmware
+    ];
+    enableAllFirmware = true;
+    cpu.amd.updateMicrocode = lib.mkDefault config.hardware.enableRedistributableFirmware;
+  };
+}

systems/ceres/config/networking.nix

@@ -0,0 +1,42 @@
+{
+  lib,
+  flake,
+  ...
+}:
+let
+  inherit (flake.config.machines.devices) ceres;
+in
+{
+  networking = {
+    hostName = ceres.name;
+    networkmanager.enable = true;
+    nftables.enable = true;
+    useDHCP = lib.mkDefault true;
+    firewall = {
+      enable = true;
+      allowedTCPPorts = [
+        22 # SSH
+        25 # SMTP
+        139 # SMTP
+        587 # SMTP
+        2525 # SMTP
+      ];
+    };
+  };
+  services = {
+    avahi = {
+      enable = true;
+      openFirewall = true;
+      nssmdns4 = true;
+      publish = {
+        enable = true;
+        userServices = true;
+      };
+    };
+    sshd.enable = true;
+    openssh = {
+      enable = true;
+      settings.PasswordAuthentication = false;
+    };
+  };
+}

systems/ceres/config/sops.nix

@@ -0,0 +1,16 @@
+{ flake, ... }:
+let
+  inherit (flake.config.people)
+    user0
+    ;
+in
+{
+  sops = {
+    secrets = {
+      "discord-token" = {
+        path = "/home/${user0}/projects/zookeeper/.env";
+        owner = user0;
+      };
+    };
+  };
+}

systems/ceres/config/wireguard.nix

@@ -0,0 +1,73 @@
+{ config, flake, ... }:
+let
+  inherit (flake.config.services) instances;
+  inherit (flake.config.machines.devices) mars deimos ceres;
+  service = instances.wireGuard;
+in
+{
+  networking = {
+    firewall = {
+      allowedTCPPorts = [
+        service.ports.port0
+      ];
+      allowedUDPPorts = [
+        service.ports.port0
+        service.ports.port1
+      ];
+    };
+
+    nat = {
+      enable = true;
+      enableIPv6 = true;
+      externalInterface = "eth0";
+      internalInterfaces = [ "wg0" ];
+    };
+
+    wireguard.interfaces = {
+      wg0 = {
+        ips = [ "${ceres.wireguard.ip0}/24" ];
+        listenPort = service.ports.port1;
+        privateKeyFile = config.sops.secrets."${service.name}-private".path;
+        peers = [
+          # if you need to create a new key pair
+          # wg genkey | save --raw --force privatekey
+          # open privatekey | wg pubkey | save --raw --force publickey
+          {
+            publicKey = "9zfRPxkxTLHM9tABC8lIaDMrzdjcF2l1mtG82uqGKUQ=";
+            allowedIPs = [ "${mars.wireguard.ip0}/32" ];
+          }
+          {
+            publicKey = "hKbvOlvKdWAlq45rfV3ggwOI8xqiqVWweXV+2GQx/0I=";
+            allowedIPs = [ "${deimos.wireguard.ip0}/32" ];
+          }
+        ];
+      };
+    };
+  };
+
+  sops =
+    let
+      sopsPath = secret: {
+        path = "${service.sops.path0}/${service.name}-${secret}-pass";
+        owner = "root";
+        mode = "600";
+      };
+    in
+    {
+      secrets = builtins.listToAttrs (
+        map
+          (secret: {
+            name = "${service.name}-${secret}";
+            value = sopsPath secret;
+          })
+          [
+            "private"
+            "public"
+          ]
+      );
+    };
+
+  boot.kernel.sysctl = {
+    "net.ipv4.ip_forward" = 1;
+  };
+}

systems/ceres/default.nix

@@ -0,0 +1,17 @@
+{ lib, ... }:
+let
+  configPath = ./config;
+
+  ceresImports =
+    let
+      files = builtins.attrNames (builtins.readDir configPath);
+    in
+    map (name: configPath + "/${name}") (
+      builtins.filter (name: builtins.match ".*\\.nix$" name != null) files
+    );
+in
+{
+  imports = ceresImports;
+  nixpkgs.hostPlatform = lib.mkForce "x86_64-linux";
+  system.stateVersion = lib.mkForce "24.05";
+}