dotfiles/profiles/user1/default.nix

{
  config,
  flake,
  pkgs,
  lib,
  ...
}:
let
  inherit (flake) self;
  inherit (flake.config.people) user1;
  inherit (flake.config.machines) devices;
  inherit (flake.config.people.users.${user1}) name paths;
  hostname = config.networking.hostName;
in
{
  users = {
    users.${user1} = {
      description = name;
      name = user1;
      isNormalUser = true;
      shell = pkgs.nushell;
      extraGroups = [
        "adbusers"
        "disk"
        "libvirtd"
        "netdev"
        "networkmanager"
        "plugdev"
        "samba"
        "vboxusers"
        "wheel"
      ];
    };
  };
  home-manager.users = {
    ${user1} = {
      home = {
        username = user1;
        homeDirectory = "/home/${user1}";
        file = {
          "./.config/scripts/get_weather.sh" = {
            source = ./files/scripts/get_weather.sh;
            executable = true;
          };
          ".config/wallpaper" = {
            source = ./files/wallpaper;
            recursive = true;
          };
          "./.config/vesktop/themes/macchiato-theme.css" = {
            source = ./files/themes/vesktop/macchiato-theme.css;
          };
        };
        sessionVariables = {
          VISUAL = lib.getExe pkgs.zed-editor;
          GTK_THEME = "catppuccin-macchiato-mauve-compact";
        };
      };
      imports = [
        {
          home.stateVersion = config.system.stateVersion;
        }
        {
          imports = [
            self.homeModules."${devices.${hostname}.name}-${user1}"
          ];
        }
      ];
    };
  };
  systemd.tmpfiles = {
    rules =
      [
        "d ${paths.path0} 0755 ${user1} users -"
      ]
      ++ (map (path: "d /home/${user1}/${path} 0755 ${user1} users -") [
        "Files"
        "Files/Scripts"
        "Files/Games"
        "Files/Screenshots"
      ])
      ++ (map (path: "R /home/${user1}/${path} 0755 ${user1} users - -") [
        "Desktop"
        "Documents"
        "Music"
        "Pictures"
        "Public"
        "Templates"
        "Videos"
      ]);
  };
}