dotfiles/modules/nixos/services/opencloud/default.nix

{ config, flake, ... }:
let
  inherit (flake.config.services.instances) opencloud web caddy;
  service = opencloud;
  localhost = web.localhost.address1;
  host = service.domains.url0;
in
{
  services = {
    opencloud = {
      enable = true;
      url = "http://${localhost}:${toString service.ports.port0}";
      port = service.ports.port0;
      address = localhost;
      stateDir = "/var/lib/${service.name}";
      environmentFile = config.sops.secrets."${service.name}/env".path;
    };
    caddy = {
      virtualHosts = {
        ":${toString caddy.ports.port4}" = {
          extraConfig = ''
            reverse_proxy http://${localhost}:${toString service.ports.port0}
          '';
        };
      };
    };
  };
  sops =
    let
      sopsPath = secret: {
        path = "${service.sops.path0}/${service.name}-${secret}";
        owner = service.name;
        mode = "600";
      };
    in
    {
      secrets = builtins.listToAttrs (
        map
          (secret: {
            name = "${service.name}/${secret}";
            value = sopsPath secret;
          })
          [
            "env"
          ]
      );
    };

  systemd = {
    tmpfiles.rules = [
      "Z ${service.sops.path0} 755 ${service.name} ${service.name} -"
    ];
  };

  networking = {
    firewall = {
      allowedTCPPorts = [
        service.ports.port0
        caddy.ports.port4
      ];
    };
  };
}