dotfiles/modules/nixos/services/opencloud/default.nix

{ config, flake, ... }:
let
  inherit (flake.config.machines.devices) ceres;
  inherit (flake.config.services.instances) opencloud web;
  service = opencloud;
  localhost = web.localhost.address1;
  host = service.domains.url0;
in
{
  services = {
    opencloud = {
      enable = true;
      url = "https://${host}:${builtins.toString service.ports.port0}";
      port = service.ports.port0;
      address = localhost;
      stateDir = "/var/lib/${service.name}";
      environment = {
        OC_INSECURE = "true";
      };
      environmentFile = config.sops.secrets."${service.name}-pass".path;
    };
    caddy = {
      virtualHosts = {
        "${host}" = {
          extraConfig = ''
            reverse_proxy ${localhost}:${toString service.ports.port0}

            tls ${service.ssl.cert} ${service.ssl.key}
          '';
        };
      };
    };
  };

  sops =
    let
      sopsPath = secret: {
        path = "${service.sops.path0}/${service.name}-${secret}";
        owner = service.name;
        mode = "600";
      };
    in
    {
      secrets = builtins.listToAttrs (
        map
          (secret: {
            name = "${service.name}-${secret}";
            value = sopsPath secret;
          })
          [
            "pass"
          ]
      );
    };

  fileSystems."/var/lib/${service.name}" = {
    device = service.paths.path0;
    fsType = "none";
    options = [
      "bind"
    ];
    depends = [
      ceres.storage0.mount
    ];
  };

  systemd.tmpfiles.rules = [
    "Z ${service.paths.path0} 755 ${service.name} ${service.name} -"
    "Z ${service.sops.path0} 755 ${service.name} ${service.name} -"
  ];

  networking = {
    firewall = {
      allowedTCPPorts = [
        service.ports.port0
      ];
    };
  };
}