dotfiles/systems/laptop/filesystem.nix

{
  flake,
  config,
  ...
}: let
  inherit (flake.config.people) user0 user1 user2;
  inherit (flake.config.system.device) laptop nas server;

  synologySecrets = config.sops.secrets."network/synology".path;
  serverSecrets = config.sops.secrets."network/server".path;
in {
  fileSystems = let
    synologyDrives = [
      "folder0"
      "folder1"
      "folder4"
    ];

    sambaDrives = [
      "samba0"
    ];

    synologyMounts = folder: {
      name = "${nas.${folder}.mount}";
      value = {
        device = nas.${folder}.device;
        fsType = "cifs";
        options = nas.${folder}.options ++ ["credentials=${synologySecrets}"];
      };
    };

    sambaMounts = samba: {
      name = "${server.${samba}.mount}";
      value = {
        device = server.${samba}.device;
        fsType = "cifs";
        options = server.${samba}.options ++ ["credentials=${serverSecrets}"];
      };
    };
  in
    {
      "/" = {
        device = "/dev/disk/by-uuid/aae33e00-125e-4f1c-b9aa-9fc512335b7f";
        fsType = "ext4";
      };
      "/boot" = {
        device = "/dev/disk/by-uuid/C506-9E18";
        fsType = "vfat";
        options = laptop.boot.options;
      };
    }
    // (builtins.listToAttrs (map synologyMounts synologyDrives))
    // (builtins.listToAttrs (map sambaMounts sambaDrives));

  swapDevices = [
    {device = "/dev/disk/by-uuid/68d6072a-e21b-4d11-88fd-22c5b9932a50";}
  ];

  systemd.tmpfiles.rules = [
    "Z ${config.home-manager.users.${user0}.home.homeDirectory} 0755 ${user0} users -"
    "Z ${config.home-manager.users.${user1}.home.homeDirectory} 0755 ${user1} users -"
    "Z ${config.home-manager.users.${user2}.home.homeDirectory} 0755 ${user2} users -"
  ];

  services.udisks2.enable = true;
}