dotfiles/packages/website/default.nix

{
  inputs,
  lib,
  ...
}:
{
  perSystem =
    { pkgs, system, ... }:
    {
      devShells.website = pkgs.mkShell {
        buildInputs = builtins.attrValues {
          inherit (pkgs) nil;
          inherit (inputs.nixpkgs-stable.legacyPackages.${system}.elmPackages)
            elm
            elm-format
            elm-land
            elm-language-server
            elm-review
            elm-test
            ;
        };
      };

      packages =
        let
          pkgs' = pkgs.extend inputs.mkElmDerivation.overlays.mkElmDerivation;
        in
        {
          website = pkgs'.mkElmDerivation {
            name = "upRootNutrition";
            src = ./frontend;

            nativeBuildInputs = builtins.attrValues {
              inherit (inputs.nixpkgs-stable.legacyPackages.${system}.elmPackages)
                elm
                elm-land
                ;
            };

            buildPhase = ''
              ${lib.getExe pkgs'.elm-land} build
            '';

            installPhase = ''
              mkdir -p "$out"
              cp -r dist/* "$out/"
            '';
          };
        };
    };
}