dotfiles/modules/nixos/homelab/guests/minecraft/config/default.nix

{
  flake,
  ...
}:
let
  inherit (flake.config.people) user0;
  inherit (flake.config.services) instances;
  serviceCfg = instances.minecraft;
in
{
  minecraftVM =
    {
      user,
      ip,
      mac,
      userMac,
      ssh,
      port,
      mnt,
      config,
      whitelist,
      worldNumber,
    }:
    {
      microvm.vms = {
        "${serviceCfg.name}-world${worldNumber}" = {
          autostart = true;
          restartIfChanged = true;
          config = {
            system.stateVersion = "24.05";
            time.timeZone = "America/Winnipeg";
            users.users.root.openssh.authorizedKeys.keys = flake.config.people.users.${user0}.sshKeys;
            services = {
              minecraft-server = {
                enable = true;
                eula = true;
                openFirewall = true;
                declarative = true;
                serverProperties = {
                  "rcon.password" = "/etc/${serviceCfg.name}-secrets/world${worldNumber}";
                  server-port = port;
                }
                // config;
                whitelist = whitelist;
              };
              openssh = {
                enable = true;
                settings = {
                  PasswordAuthentication = false;
                  PermitRootLogin = "prohibit-password";
                };
              };
            };
            networking.firewall.allowedTCPPorts = [
              22
              port
            ];
            systemd = {
              services = {
                "${serviceCfg.name}-copy-secrets" = {
                  description = "Copy secrets from virtiofs to local filesystem";
                  before = [ "minecraft-server.service" ];
                  requiredBy = [ "minecraft-server.service" ];

                  serviceConfig = {
                    Type = "oneshot";
                    RemainAfterExit = true;
                  };
                  script = ''
                    mkdir -p /etc/${serviceCfg.name}-secrets
                    cp /run/secrets/world${worldNumber} /etc/${serviceCfg.name}-secrets/world${worldNumber}
                    chmod 755 /etc/${serviceCfg.name}-secrets
                    chmod 644 /etc/${serviceCfg.name}-secrets/*
                  '';
                };
                systemd-networkd.wantedBy = [ "multi-user.target" ];
              };
              network = {
                enable = true;
                networks."20-lan" = {
                  matchConfig.Name = "enp0s5";
                  addresses = [
                    { Address = "${ip}/24"; }
                  ];
                  routes = [
                    {
                      Destination = "0.0.0.0/0";
                      Gateway = "192.168.50.1";
                    }
                  ];
                  dns = [
                    "1.1.1.1"
                    "8.8.8.8"
                  ];
                };
              };
              tmpfiles.rules = [
                "d /var/lib/${serviceCfg.name} 0755 ${serviceCfg.name} ${serviceCfg.name} -"
                "Z /var/lib/${serviceCfg.name} 0755 ${serviceCfg.name} ${serviceCfg.name} -"
              ];
            };
            microvm = {
              vcpu = 4;
              mem = 1024 * 4;
              hypervisor = "qemu";
              interfaces = [
                {
                  type = "tap";
                  id = "vm-mc-${worldNumber}";
                  mac = mac;
                }
                {
                  type = "user";
                  id = "vmuser-craft";
                  mac = userMac;
                }
              ];
              forwardPorts = [
                {
                  from = "host";
                  host.port = ssh;
                  guest.port = 22;
                }
              ];
              shares = [
                {
                  mountPoint = "/nix/.ro-store";
                  proto = "virtiofs";
                  source = "/nix/store";
                  tag = "read_only_nix_store";
                }
                {
                  mountPoint = "/var/lib/${serviceCfg.name}";
                  proto = "virtiofs";
                  source = "${mnt}/${serviceCfg.name}/world${worldNumber}";
                  tag = "${serviceCfg.name}_mc${worldNumber}_data";
                }
                {
                  mountPoint = "/run/secrets";
                  proto = "virtiofs";
                  source = "/run/secrets/${serviceCfg.name}";
                  tag = "host_secrets";
                }
              ];
            };
          };
        };
      };
      networking.firewall.allowedTCPPorts = [ port ];

      systemd.tmpfiles.rules = [
        "d ${mnt}/${serviceCfg.name} 0751 microvm wheel - -"
        "d ${mnt}/${serviceCfg.name}/world${worldNumber} 0751 microvm wheel - -"
        "Z ${mnt}/${serviceCfg.name}/world${worldNumber} 0755 microvm wheel - -"
      ];

      sops.secrets = {
        "${serviceCfg.name}/world${worldNumber}" = {
          owner = "root";
          mode = "0600";
        };
      };
    };
}