dotfiles/modules/nixos/guests/opencloud/ceresOpenCloud/default.nix

{
  config,
  flake,
  pkgs,
  ...
}:
let
  inherit (flake.config.people) user0;
  inherit (flake.config.services) instances;
  serviceCfg = instances.opencloud;
  hostCfg = instances.web;
  dns = instances.web.dns.provider1;
  localhost = instances.web.localhost.address1;
  host = "${serviceCfg.subdomain}.${flake.inputs.linkpage.secrets.domains.projectsite}";
  dnsPath = "dns/${dns}";
in
{
  microvm.vms = {
    projectcloud = {
      autostart = true;
      restartIfChanged = true;
      config = {
        system.stateVersion = "24.05";
        time.timeZone = "America/Winnipeg";
        users.users.root.openssh.authorizedKeys.keys = flake.config.people.users.${user0}.sshKeys;
        services = {
          opencloud = {
            enable = true;
            url = "https://${host}";
            port = serviceCfg.ports.port0;
            address = localhost;
            stateDir = "/var/lib/${serviceCfg.name}";
            environmentFile = "/run/secrets/projectenv";
          };

          openssh = {
            enable = true;
            settings = {
              PasswordAuthentication = false;
              PermitRootLogin = "prohibit-password";
            };
          };
        };

        networking.firewall.allowedTCPPorts = [
          22 # SSH
          587 # SMTP
          serviceCfg.ports.port0
        ];

        systemd = {
          services = {
            opencloud = {
              path = [ pkgs.inotify-tools ];
            };
          };
          network = {
            enable = true;
            networks."20-lan" = {
              matchConfig.Name = "enp0s5";
              addresses = [
                { Address = "${serviceCfg.interface.ip}/24"; }
              ];
              routes = [
                {
                  Destination = "${hostCfg.localhost.address1}/0";
                  Gateway = serviceCfg.interface.gate;
                }
              ];
              dns = [
                "1.1.1.1"
                "8.8.8.8"
              ];
            };
          };

          tmpfiles.rules = [
            "Z ${serviceCfg.varPaths.path0} 0755 ${serviceCfg.name} ${serviceCfg.name} -"
          ];

        };

        systemd.services.systemd-networkd.wantedBy = [ "multi-user.target" ];

        microvm = {
          vcpu = 4;
          mem = 4096;
          hypervisor = "qemu";
          interfaces = [
            {
              type = "tap";
              id = serviceCfg.interface.id;
              mac = serviceCfg.interface.mac;
            }
            {
              type = "user";
              id = serviceCfg.interface.idUser;
              mac = serviceCfg.interface.macUser;
            }
          ];
          forwardPorts = [
            {
              from = "host";
              host.port = serviceCfg.interface.ssh;
              guest.port = 22;
            }
          ];
          shares = [
            {
              mountPoint = "/nix/.ro-store";
              proto = "virtiofs";
              source = "/nix/store";
              tag = "read_only_nix_store";
            }
            {
              mountPoint = "/var/lib/${serviceCfg.name}";
              proto = "virtiofs";
              source = serviceCfg.mntPaths.path0;
              tag = "${serviceCfg.name}_data";
            }
            {
              mountPoint = "/run/secrets";
              proto = "virtiofs";
              source = "/run/secrets/${serviceCfg.name}";
              tag = "host_secrets";
            }
          ];
        };
      };
    };
  };

  security.acme.certs."${host}" = {
    dnsProvider = dns;
    environmentFile = config.sops.secrets.${dnsPath}.path;
    group = "caddy";
  };

  services.caddy.virtualHosts = {
    "${host}" = {
      extraConfig = ''
        reverse_proxy ${serviceCfg.interface.ip}:${toString serviceCfg.ports.port0} {
          header_up X-Real-IP {remote_host}
        }

        redir /.well-known/carddav /remote.php/dav/ 301
        redir /.well-known/caldav /remote.php/dav/ 301

        tls /var/lib/acme/${host}/fullchain.pem /var/lib/acme/${host}/key.pem 
      '';
    };
  };

  users.users.caddy.extraGroups = [ "acme" ];

  systemd = {
    tmpfiles.rules = [
      "d ${serviceCfg.mntPaths.path0} 0751 microvm wheel - -"
      "d ${serviceCfg.mntPaths.path0}/storage 0755 opencloud opencloud - -"
      "d ${serviceCfg.mntPaths.path0}/storage/users 2775 opencloud wheel - -"
    ];
  };

  sops.secrets = {
    "${serviceCfg.name}/projectenv" = {
      owner = "root";
      mode = "0600";
    };
  };

}