dotfiles/config/default.nix

{lib, ...}: let
  stringType = lib.mkOption {
    type = lib.types.str;
  };
  intType = lib.mkOption {
    type = lib.types.int;
  };
  listType = lib.mkOption {
    type = lib.types.listOf lib.types.str;
  };

  numOptions = 20;

  genOptions = config: prefix:
    builtins.listToAttrs (
      map
      (i: {
        name = "${prefix}${toString i}";
        value = config;
      })
      (builtins.genList (i: i) numOptions)
    );
in let
  userSubmodule = lib.types.submodule {
    options = {
      name = stringType;
      sshKeys = listType;
      group = stringType;
      aliases = genOptions stringType "name";
      email = genOptions stringType "address";
      paths = genOptions stringType "path";
    };
  };
  instanceSubmodule = lib.types.submodule {
    options = {
      subdomain = stringType;
      label = stringType;
      name = stringType;
      domains = genOptions stringType "url";
      dns = genOptions stringType "provider";
      localhost = genOptions stringType "address";
      email = genOptions stringType "address";
      sops = genOptions stringType "path";
      paths = genOptions stringType "path";
      ports = genOptions intType "port";
      ssl = {
        cert = stringType;
        key = stringType;
      };
    };
  };
  deviceSubmodule = lib.types.submodule {
    options = let
      mountConfig = {
        mount = stringType;
        device = stringType;
        options = listType;
      };
    in
      {
        boot = mountConfig;
        ip = genOptions stringType "address";
        label = stringType;
        name = stringType;
        sync = stringType;
      }
      // genOptions mountConfig "folder"
      // genOptions mountConfig "samba"
      // genOptions mountConfig "storage";
  };
in {
  options = {
    services = lib.mkOption {
      type = lib.types.submodule {
        options =
          builtins.listToAttrs (map (name: {
              inherit name;
              value = stringType;
            })
            [
              "acme"
              "caddy"
              "castopod"
              "forgejo"
              "jellyfin"
              "mastodon"
              "matrix"
              "minecraft"
              "nextcloud"
              "nginx"
              "ollama"
              "owncast"
              "peertube"
              "postgresql"
              "samba"
              "syncthing"
              "synology"
              "vaultwarden"
              "web"
              "wiki"
              "writefreely"
            ])
          // {
            instances = lib.mkOption {
              type = lib.types.attrsOf instanceSubmodule;
            };
          };
      };
    };
    machines = lib.mkOption {
      type = lib.types.submodule {
        options =
          builtins.listToAttrs (map (name: {
              inherit name;
              value = stringType;
            })
            [
              "desktop"
              "laptop"
              "nas"
              "phone"
              "printer0"
              "printer1"
              "server"
              "tablet"
            ])
          // {
            devices = lib.mkOption {
              type = lib.types.attrsOf deviceSubmodule;
            };
          };
      };
    };
    people = lib.mkOption {
      type = lib.types.submodule {
        options =
          builtins.listToAttrs (
            map (name: {
              inherit name;
              value = stringType;
            })
            [
              "user0"
              "user1"
            ]
          )
          // {
            users = lib.mkOption {
              type = lib.types.attrsOf userSubmodule;
            };
          };
      };
    };
  };

  config = {
    people = import ./users.nix;
    services = import ./instances.nix;
    machines = import ./devices.nix;
  };
}