{
  config,
  flake,
  ...
}:
let
  inherit (flake.config.people) user0;
  inherit (flake.config.services) instances;
  serviceCfg = flake.config.services.instances.forgejo;
  smtpCfg = flake.config.services.instances.smtp;
  hostCfg = flake.config.services.instances.web;
  host = serviceCfg.domains.url0;
  dns0 = instances.web.dns.provider0;
  dns0Path = "dns/${dns0}";
in
{
  users.users.caddy.extraGroups = [ "acme" ];

  security.acme.certs."${host}" = {
    dnsProvider = dns0;
    environmentFile = config.sops.secrets.${dns0Path}.path;
    group = "caddy";
  };

  microvm.vms = {
    ${serviceCfg.name} = {
      autostart = true;
      restartIfChanged = true;
      config = {
        system.stateVersion = "24.05";
        time.timeZone = "America/Winnipeg";
        users.users.root.openssh.authorizedKeys.keys = flake.config.people.users.${user0}.sshKeys;
        services = {
          ${serviceCfg.name} = {
            enable = true;
            lfs.enable = true;
            secrets = {
              mailer.PASSWD = "/run/secrets/smtp";
            };
            settings = {
              server = {
                DOMAIN = host;
                ROOT_URL = "https://${host}/";
                HTTP_PORT = serviceCfg.ports.port0;
              };
              # If you need to start from scratch, don't forget to turn this off again
              service.DISABLE_REGISTRATION = true;
              actions = {
                ENABLED = true;
                DEFAULT_ACTIONS_URL = "github";
              };
              mirror = {
                ENABLED = true;
              };
              mailer = {
                ENABLED = true;
                SMTP_ADDR = smtpCfg.hostname;
                FROM = smtpCfg.email.address1;
                USER = smtpCfg.email.address1;
                PROTOCOL = "${smtpCfg.name}+${smtpCfg.records.record1}";
                SMTP_PORT = smtpCfg.ports.port1;
                SEND_AS_PLAIN_TEXT = true;
                USE_CLIENT_CERT = false;
              };
            };
          };

          openssh = {
            enable = true;
            settings = {
              PasswordAuthentication = false;
              PermitRootLogin = "prohibit-password";
            };
          };
        };

        networking.firewall.allowedTCPPorts = [
          22 # SSH
          25 # SMTP
          139 # SMTP
          587 # SMTP
          2525 # SMTP
          serviceCfg.ports.port0
        ];

        fileSystems."/tmp" = {
          device = "tmpfs";
          fsType = "tmpfs";
          options = [
            "size=4G"
            "mode=1777"
          ];
        };

        systemd = {
          network = {
            enable = true;
            networks."20-lan" = {
              matchConfig.Name = "enp0s5";
              addresses = [ { Address = "${serviceCfg.interface.ip}/24"; } ];
              routes = [
                {
                  Destination = "${hostCfg.localhost.address1}/0";
                  Gateway = serviceCfg.interface.gate;
                }
              ];
              dns = [
                "1.1.1.1"
                "8.8.8.8"
              ];
            };
          };

          tmpfiles.rules = [
            "Z ${serviceCfg.varPaths.path0} 0755 ${serviceCfg.name} ${serviceCfg.name} -"
            # "Z /var/lib/postgresql 0755 postgres postgres -"
          ];
        };

        systemd.services.systemd-networkd.wantedBy = [ "multi-user.target" ];

        microvm = {
          vcpu = 2;
          mem = 3072;
          hypervisor = "qemu";
          interfaces = [
            {
              type = "tap";
              id = serviceCfg.interface.id;
              mac = serviceCfg.interface.mac;
            }
            {
              type = "user";
              id = serviceCfg.interface.idUser;
              mac = serviceCfg.interface.macUser;
            }
          ];
          forwardPorts = [
            {
              from = "host";
              host.port = serviceCfg.interface.ssh;
              guest.port = 22;
            }
          ];
          shares = [
            {
              mountPoint = "/nix/.ro-store";
              proto = "virtiofs";
              source = "/nix/store";
              tag = "read_only_nix_store";
            }
            {
              mountPoint = "/var/lib/${serviceCfg.name}";
              proto = "virtiofs";
              source = "${serviceCfg.mntPaths.path0}";
              tag = "${serviceCfg.name}_data";
            }
            {
              mountPoint = "/run/secrets";
              proto = "virtiofs";
              source = "/run/secrets/${serviceCfg.name}";
              tag = "host_secrets";
            }
          ];
        };
      };
    };
  };

  systemd.tmpfiles.rules = [
    "d ${serviceCfg.mntPaths.path0} 0751 microvm wheel - -"
  ];

  services.caddy.virtualHosts."${host}" = {
    extraConfig = ''
      reverse_proxy ${serviceCfg.interface.ip}:${toString serviceCfg.ports.port0} {
        header_up X-Real-IP {remote_host}
      }

      tls ${serviceCfg.ssl.cert} ${serviceCfg.ssl.key}

      encode zstd gzip
    '';
  };

  sops.secrets = {
    "${serviceCfg.name}/smtp" = {
      owner = "root";
      mode = "0600";
    };
  };
}
